Select Page

# Model with mixed first-order and zero-order absorption, or parallel first-order

Some drugs can display complex absorption kinetics. Common examples are mixed first-order and zero-order absorptions, either sequentially or simultaneously, and fast and slow parallel first-order absorptions.

A few examples of those kinds of absorption kinetics are listed below:

More examples of complex absorptions are given in:

Zhou, H. (2003). Pharmacokinetic Strategies in Deciphering Atypical Drug Absorption Profiles. The Journal of Clinical Pharmacology, 43(3), 211–227.

### Mlxtran models

For the examples below, we consider a single compartment and a linear elimination. The model is described using macros. In all examples, a fraction F of the dose is absorbed via the zero-order process and the remaining 1-F fraction of the dose is absorbed via a first-order process. In the data set, the dose lines must not be duplicated. A single dose line can be split into two processes using the keyword p in the absorption macros.
As the parameter F must stay within [0,1], a logit distribution must be chosen in the Monolix GUI.

#### Parallel first-order

Parallel first-order absorptions can have various causes, among other: absorption via water and lipid routes for dermal administrations, absorption in the bucal cavity and GI tract for sublingual administrations, progressive solubilisation along the GI tract and subsequent intestinal absorption for oral administrations or simply two different absorption sites.

[LONGITUDINAL]
input = {ka1, ka2, Tlag, F, V, Cl}

PK:
compartment(cmt=1, volume=V, concentration=Cc)
absorption(cmt=1, ka=ka1, p=F)
absorption(cmt=1, ka=ka2, Tlag, p=1-F)
elimination(cmt=1, Cl)

OUTPUT:
output = {Cc}

#### Simultaneous zero-order and first-order

The drug is simultaneously absorbed via a first-order and a zero-order process, which both start at the administration time (no lag time).

[LONGITUDINAL]
input = {ka, Tk0, F, V, Cl}

PK:
compartment(cmt=1, volume=V, concentration=Cc)
absorption(cmt=1, Tk0, p=F)
absorption(cmt=1, ka, p=1-F)
elimination(cmt=1, Cl)

OUTPUT:
output = {Cc}

#### Sequential zero-order followed by first order

The drug is first absorbed via a zero-order process during a time Tk0. Once this is finished, the remaining fraction is absorbed via a first-order process, which starts with a lag time Tk0.

[LONGITUDINAL]
input = {ka, Tk0, F, V, Cl}

PK:
compartment(cmt=1, volume=V, concentration=Cc)
absorption(cmt=1, Tk0, p=F)
absorption(cmt=1, Tlag=Tk0, ka, p=1-F)
elimination(cmt=1, Cl)

OUTPUT:
output = {Cc}

#### Sequential first-order followed by zero-order

Because a first-order absorption never ends (there is always a little bit of drug remaining in the depot compartment and being absorbed into the central compartment), the two absorption processes will not be truly sequential. Yet we can introduce a lag time for the zero-order process, such that the zero-order process starts when the first-order process becomes negligible.

[LONGITUDINAL]
input = {ka, Tk0, F, Tlag, V, Cl}

PK:
compartment(cmt=1, volume=V, concentration=Cc)
absorption(cmt=1, Tk0, p=F, Tlag)
absorption(cmt=1, ka, p=1-F)
elimination(cmt=1, Cl)

OUTPUT:
output = {Cc}

#### Two administration routes and mixed absorption

Below we present a model for an administration scheme with two different routes: some doses are administrated via iv and some orally. The two routes are distinguished using an identifier: in the data set the doses are tagged using the ADM column with either ADM=1 (iv for instance) or ADM=2 (oral). In the model, the adm keyword is used to associate a route to specific doses.

In addition, we introduce the total bioavailability for the oral route Foral.

[LONGITUDINAL]
input = {ka, Tk0, F, Foral, Tlag, V, Cl}

PK:
compartment(cmt=1, volume=V, concentration=Cc)
elimination(cmt=1, Cl)

OUTPUT:
output = {Cc}

### Sequential zero-order/first-order absorption exploration in Mlxplore

We investigate the sequential zero-order/first-order absorption using the following Mlxplore script:

<MODEL>
[LONGITUDINAL]
input = {ka, Tk0, F, V, Cl}

PK:
compartment(cmt=1, volume=V, concentration=Cc)
absorption(cmt=1, Tk0, p=F)
absorption(cmt=1, Tlag=Tk0, ka, p=1-F)
elimination(cmt=1, Cl)

OUTPUT:
output = {Cc}

<PARAMETER>
ka=1
Tk0 = 8
F = 0.5
V = 10
Cl = 1

<DESIGN>
grid=0.1:0.1:100